Apple Reference & Presen…tion Library 2 (Reseller)/Apple R&P Lib Reseller v2.0.iso/2-Presentations/Apple Products/OASIS Stack 1.1/OASIS Stack 1.1/background_46202.txt

Text File | 1989-07-21 | 26KB | 1,034 lines

-- background: 46202 from stack: in.1
-- bmap block id: 46523
-- flags: 4000
-- background id: 0
-- name: Builder
----- HyperTalk script -----
------------------------------------------------------------------------
--
--   Handlers for system messages
--
------------------------------------------------------------------------

on openCard
  global building,selectList
  if building is the short ID of this card then
    set hilite of background button "Add" to true
  else
    set hilite of background button "Add" to false
  end if
  -- Unhighlight buttons (may not be necessary anymore?)
  repeat with n = 1 to the number of card buttons
    set the hilite of card button n to false
  end repeat
  -- Set next phase, previous phase buttons
  if the short name of next card is "Builder Guard" or the short name of this card is "Builder Guard" then
    set the visible of background button "Next" to false
  else
    set the visible of background button "Next" to (field "Title" of next card) is field "Title"
  end if
  if the short name of prev card is "Builder Map" then
    set the visible of background button "Prev" to false
  else
    set the visible of background button "Prev" to (field "Title" of prev card) is field "Title"
  end if
  -- Set next slice, previous slice buttons
  set the visible of background button "Next Slice" to (field "Title" ≠ last line of card field "Slices" of card "Builder Map")
  set the visible of background button "Prev Slice" to (field "Title" ≠ first line of card field "Slices" of card "Builder Map")
end openCard


on openBackground
  global dragged, nuked
  put false into dragged
  put false into nuked
  pass openBackground
end openBackground

on closeCard
  global selectList
  put empty into selectList
end closeCard

on newCard
  global building, silent
  get empty
  if not silent then answer "A new slice, or a next phase of this one?" with "Slice" or "Phase"
  if it is "Slice" or silent then
    put "true" into card field "Changed" of card "Builder Map"
    put the short ID of this card into building
    set the hilight of background button "Add" to true
    select char 1 of field "Title"
  else
    lock screen
    doMenu "Delete Card"
    go prev
    if field "Order" is empty then put 1 into field "Order"
    doMenu "Copy Card"
    doMenu "Paste Card"
    add 1 to field "Order"
    put the short ID of this card into building
    set the hilight of background button "Add" to true
  end if
  put false into silent
  pass newCard
end newCard

on deleteCard
  global building
  if not exists(building) then put empty into building
  put "true" into card field "Changed" of card "Builder Map"
  pass deleteCard
end deleteCard

------------------------------------------------------------------------
--
--   Handlers for mouse messages
--
------------------------------------------------------------------------

on mouseDown
  global oldCenter, delta, dragged, nuked -- for dragging
  global lastClick -- for double clicking
  global selectList -- for selecting

  -- detect double-clicks
  put (the ticks - lastClick) < 110 and (the short ID of the target is in selectList) and not dragged into doubleClick

  put false into nuked
  if the name of the target contains "card button" then
    put false into dragged
    put item 1 of the loc of the target into oldCenter

    -- main event dispatcher
    if doubleClick then
      push card
      go to card ID (word 1 of the script of the target)
    else
      selectIt
      if the optionKey is down then
        deleteEm
      end if
    end if
  else
    -- click outside button; deselect
    clearSelection
  end if
  put the ticks into lastClick
end mouseDown

on mouseStillDown
  global dragged, delta
  if the name of the target contains "card button" then
    if dragged then
      get the loc of the target
      put item 1 of the mouseLoc-delta into item 1 of it
      put max(min(item 1 of it, the right of background button "limits"), the left of background button "limits") into item 1 of it
      set the loc of the target to it
    else
      if abs(item 1 of the mouseLoc-item 1 of the clickLoc) > 2 then
        put true into dragged
        put item 1 of the mouseLoc-item 1 of the clickLoc into delta
      end if
    end if
  end if
end mouseStillDown

on mouseUp
  global dragged,nuked,lastClick
  if not nuked then
    if the name of the target contains "card button" then
      if dragged then
        shiftEm
        subtract 200 from lastClick
      end if
    end if
  end if
end mouseUp

------------------------------------------------------------------------
--
--   Mouse actions:  select, double-click, drag, option-click
--
------------------------------------------------------------------------

on selectIt
  global selectList,lastClick
  if the shiftKey is up then clearSelection
  set the hilite of the target to true
  put the short ID of the target & return before selectList
end selectIt

on clearSelection
  global selectList
  repeat with n = 1 to the number of lines of selectList
    set the hilite of card button ID (line n of selectList) to false
  end repeat
  put empty into selectList
end clearSelection

on deleteEm
  global selectList, nuked
  lock screen
  choose button tool
  repeat with n = 1 to the number of lines of selectList
    put line n of selectList into itsID
    put layer(field "Layer" of card ID (word 1 of the script of button ID itsID)) into itsLayer
    put item 1 of the loc of card button ID itsID into itsCenter
    moveIcon itsID,itsLayer,itsCenter,0
    select card button ID itsID
    doMenu "Cut Button"
  end repeat
  put empty into selectList
  put true into nuked -- to eliminate an error on mouseUp
  choose browse tool
end deleteEm

on shiftEm
  global selectList,oldCenter,delta
  lock screen
  repeat with n = 1 to the number of lines of selectList
    put (line n of selectList) into itsID
    put layer(field "Layer" of card ID (word 1 of the script of card button ID itsID)) into itsLayer
    put item 1 of the loc of card button ID itsID into itsCenter
    if the short ID of the target is not itsID then
      -- Move the flotilla
      set the loc of card button ID itsID to (item 1 of the loc of card button ID itsID)+delta,item 2 of the loc of card button ID itsID
      moveIcon itsID,itsLayer,itsCenter,itsCenter+delta
    else
      -- Move the dragged icon
      moveIcon itsID,itsLayer,oldCenter,itsCenter
    end if
  end repeat
end shiftEm

------------------------------------------------------------------------
--
--   Handlers for my messages
--
------------------------------------------------------------------------

on moveIcon itsID,itsLayer,oldCenter,newCenter
  -- Adjusts the centers and buttons fields when a button moves.
  -- If newCenter is 0, deletes it.
  --
  -- Find old center and remove
  repeat with n = 1 to the number of items in line itsLayer of field "Centers"
    if item n of line itsLayer of field "Centers" is oldCenter then
      delete item n of line itsLayer of field "Buttons"
      delete item n of line itsLayer of field "Centers"
      exit repeat
    end if
  end repeat
  if newCenter is not 0 then
    -- Insert new center in proper order.
    put the number of items in line itsLayer of field "Centers" into count
    repeat with n = 1 to count+1
      if n = count+1 then
        put the right of background button "Limits" into r
      else
        put item n of line itsLayer of field "Centers" into r
      end if
      if r > newCenter then
        put itsID & "," before item n of line itsLayer of field "Buttons"
        put newCenter & "," before item n of line itsLayer of field "Centers"
        exit repeat
      end if
    end repeat
  end if
end moveIcon

on placeIcon layer,backlink
  -- Copy the clicked button from this card to next available spot
  -- on this card.  Put the backlink and related item
  -- list into the button’s script, and draw linkage lines to other
  -- buttons on the card.
  --
  -- layer is 1= application, 2=desktop, etc.
  -- backlink is ID of calling card
  --
  -- Field "centers" is five lines, one per layer.  Each line is
  -- an itemlist of the centers of icons on that line, always in order.
  -- Field "Buttons" is five lines, one per layer.  Each line is
  -- an itemlist of the button numbers of the buttons on that line.

  global selectList
  lock screen

  -- Build an itemlist of the IDs of the related cards.
  put empty into relList
  repeat with n = 1 to the number of lines of field "Related Module" of card ID backLink
    if n > 1 then put "," after relList
    put line n of field "Related Module" of card ID backLink after relList
  end repeat

  -- find the largest open spot
  put the number of items in line layer of field "Centers" into count
  put 0 into maxSpan
  repeat with n = 1 to count+1
    if n is 1 then
      put the left of background button "limits" into gapLeft
    else
      put (item n-1 of line layer of field "Centers") into gapLeft
    end if
    if n is count+1 then
      put the right of background button "Limits" into gapRight
    else
      put (item n of line layer of field "Centers") into gapRight
    end if
    put gapRight-gapLeft into span
    put gapleft+(span div 2) into midl

    if span > maxSpan then
      put span into maxSpan
      put n into index
      put midl into theMiddle
    end if
  end repeat
  -- At this point, theMiddle is the horizontal position and index is the
  -- count of icons to the new one's right.

  -- Paste the new button.
  doMenu "Paste Button"
  choose browse tool
  put the number of card buttons into m
  set the loc of button m to theMiddle,(item 2 of the loc of background button layer)
  set the autoHilite of button m to false
  get empty
  put backlink into word 1 of it
  put relList into line 2 of it
  set the script of button m to it
  set hilite of button m to true
  put the short ID of button m into selectList
  unlock screen

  -- Adjust the Centers and Buttons fields
  put (item 1 of the loc of button m) & "," before item index of line layer of field "Centers"
  put the short ID of card button m & "," before item index of line layer of field "Buttons"

  -- Draw lines to related modules.
  choose line tool
  set lineSize to 1
  repeat with n = 1 to the number of card buttons
    if (word 1 of the script of card button n) is in relList then
      drag from the loc of card button n to the loc of card button m
    end if
  end repeat
  choose browse tool
end placeIcon

------------------------------------------------------------------------
--
--   Utility functions and sort orders
--
------------------------------------------------------------------------

function sortOrder
return "HA" && field "title" && field "order"
end sortOrder





-- part 4 (field)
-- low flags: 80
-- high flags: 0000
-- rect: left=103 top=15 right=266 bottom=449
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 0
-- font id: 3
-- text size: 12
-- style flags: 0
-- line height: 52
-- part name: Centers


-- part 12 (field)
-- low flags: 80
-- high flags: 0000
-- rect: left=350 top=57 right=311 bottom=428
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 0
-- font id: 3
-- text size: 12
-- style flags: 0
-- line height: 52
-- part name: Buttons


-- part 16 (field)
-- low flags: 80
-- high flags: 0000
-- rect: left=23 top=57 right=339 bottom=94
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 0
-- font id: 3
-- text size: 12
-- style flags: 0
-- line height: 48
-- part name:


-- part 17 (field)
-- low flags: 80
-- high flags: 0000
-- rect: left=422 top=57 right=339 bottom=493
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 0
-- font id: 3
-- text size: 12
-- style flags: 0
-- line height: 48
-- part name:


-- part 1 (field)
-- low flags: 01
-- high flags: 0000
-- rect: left=126 top=7 right=41 bottom=435
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 0
-- font id: 156
-- text size: 24
-- style flags: 0
-- line height: 32
-- part name: Title
----- HyperTalk script -----
on closeField
  put "True" into card field "Changed" of card "Builder Map"
  pass CloseField
end CloseField


-- part 36 (button)
-- low flags: 00
-- high flags: 0000
-- rect: left=15 top=52 right=101 bottom=507
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Application


-- part 37 (button)
-- low flags: 00
-- high flags: 0000
-- rect: left=15 top=103 right=153 bottom=507
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Desktop


-- part 38 (button)
-- low flags: 00
-- high flags: 0000
-- rect: left=15 top=155 right=205 bottom=507
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Toolbox


-- part 39 (button)
-- low flags: 00
-- high flags: 0000
-- rect: left=15 top=207 right=257 bottom=507
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Operating System


-- part 40 (button)
-- low flags: 00
-- high flags: 0000
-- rect: left=15 top=259 right=309 bottom=507
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Hardware


-- part 18 (button)
-- low flags: 80
-- high flags: 8000
-- rect: left=19 top=61 right=111 bottom=98
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Sample
----- HyperTalk script -----





-- part 35 (button)
-- low flags: 00
-- high flags: 0000
-- rect: left=15 top=52 right=309 bottom=507
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Limits


-- part 19 (button)
-- low flags: 80
-- high flags: A002
-- rect: left=142 top=320 right=338 bottom=210
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Redraw
----- HyperTalk script -----
on mouseDown
end mouseDown

on mouseStillDown
end mouseStillDown

on mouseUp
  repeat with j = 1 to the number of buttons
    repeat with k = 1 to j-1
      if abs(item 1 of the loc of button j - item 1 of the loc of button k) < 10 then
        moveIcon (the short name of button j), (layer(field "Layer" of card ID (word 1 of the script of button j))), item 1 of the loc of button j, item 1 of the loc of button k
        set the loc of button j to (item 1 of the loc of button k), item 2 of the loc of button j
      end if
    end repeat
  end repeat
  choose line tool
  doMenu "Select All"
  doMenu "Clear Picture"
  set lineSize to 1
  repeat with n = 1 to the number of card buttons
    repeat with m = 1 to the number of card buttons
      if word 1 of the script of card button n is in line 2 of the script of card button m then
        drag from the loc of card button n to the loc of card button m
      end if
    end repeat
  end repeat
  choose browse tool
end mouseUp



-- part 20 (button)
-- low flags: 80
-- high flags: 2000
-- rect: left=477 top=9 right=42 bottom=512
-- title width / last selected line: 0
-- icon id / first selected line: 7856 / 7856
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Next
----- HyperTalk script -----
on mouseUp
  if the commandKey is up then
    -- do regular dissolve or wipe
    if (field "Title" of next card of this background) is field "Title" of this card then
      visual effect dissolve
    else
      visual effect wipe left
    end if
    go to next card of this background
  else
    -- Copy this card to the next one
    doMenu "Copy Card"
    doMenu "Paste Card"
    newCard
  end if
end mouseUp



-- part 21 (button)
-- low flags: 00
-- high flags: 2000
-- rect: left=405 top=309 right=342 bottom=441
-- title width / last selected line: 0
-- icon id / first selected line: 19104 / 19104
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Prev Slice
----- HyperTalk script -----
on mouseDown
end mouseDown

on mouseStillDown
end mouseStillDown

on mouseUp
  if the commandKey is up then
    go to prev card
  else
    -- Make another card like this one
    doMenu "Copy Card"
    go prev
    doMenu "Paste Card"
    newCard
  end if
end mouseUp



-- part 22 (button)
-- low flags: 00
-- high flags: 0000
-- rect: left=475 top=309 right=342 bottom=512
-- title width / last selected line: 0
-- icon id / first selected line: 20955 / 20955
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Return
----- HyperTalk script -----
on mouseDown
end mouseDown

on mouseStillDown
end mouseStillDown

on mouseUp
  pop card
end mouseUp



-- part 24 (button)
-- low flags: 80
-- high flags: 8002
-- rect: left=15 top=320 right=338 bottom=69
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Add
----- HyperTalk script -----
on mouseDown
end mouseDown

on mouseStillDown
end mouseStillDown

on mouseUp
  global building
  if the hilite of me is false then
    put the short ID of this card into building
    set the hilite of me to true
  else
    put empty into building
    set the hilite of me to false
  end if
end mouseUp



-- part 26 (field)
-- low flags: 01
-- high flags: 0000
-- rect: left=434 top=7 right=41 bottom=490
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 65535
-- font id: 156
-- text size: 24
-- style flags: 0
-- line height: 32
-- part name: Order


-- part 33 (button)
-- low flags: 00
-- high flags: 2000
-- rect: left=369 top=309 right=342 bottom=406
-- title width / last selected line: 0
-- icon id / first selected line: 29848 / 29848
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Help
----- HyperTalk script -----
on mouseDown
end mouseDown

on mouseStillDown
end mouseStillDown

on mouseUp
  global startCard
  put the short ID of this card into startCard
  go card "Builder Help"
end mouseUp



-- part 34 (button)
-- low flags: 00
-- high flags: 2000
-- rect: left=440 top=309 right=342 bottom=476
-- title width / last selected line: 0
-- icon id / first selected line: 7856 / 7856
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Next Slice
----- HyperTalk script -----
on mouseDown
end mouseDown

on mouseStillDown
end mouseStillDown

on mouseUp
  set lockScreen to true
  set cursor to watch
  put field "Title" into startTitle
  repeat until field "Title" is not startTitle and field "Title" is not empty
    go to next card of this background
  end repeat
end mouseUp



-- part 42 (button)
-- low flags: 80
-- high flags: A002
-- rect: left=298 top=320 right=338 bottom=366
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Detach
----- HyperTalk script -----
on mouseDown
end mouseDown

on mouseStillDown
end mouseStillDown

on mouseUp
  global selectList
  if the number of lines of selectList < 2 then
    answer "Shift-click 2 or more icons first." with OK
  else
    set cursor to watch
    choose line tool
    set pattern to 1 -- white
    repeat with n = 2 to the number of lines in selectList
      detach line n of selectList,line n-1 of selectList
      detach line n-1 of selectList,line n of selectList
      drag from the loc of button ID (line n of selectList) to the loc of button ID (line n-1 of selectList) with optionKey
    end repeat
    choose browse tool
  end if
end mouseUp

on detach a,b
  repeat with n = 1 to the number of items of line 2 of the script of button ID a
    if item n of line 2 of the script of button ID a is word 1 of the script of button ID b then
      get the script of button ID a
      delete item n of line 2 of it
      set the script of button ID a to it
    end if
  end repeat
end detach




-- part 43 (button)
-- low flags: 80
-- high flags: A002
-- rect: left=226 top=320 right=338 bottom=294
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Connect
----- HyperTalk script -----
on mouseDown
end mouseDown

on mouseStillDown
end mouseStillDown

on mouseUp
  global selectList
  if the number of lines of selectList < 2 then
    answer "Shift-click two or more icons first." with OK
  else
    set cursor to watch
    choose line tool
    set lineSize to 1
    repeat with n = 2 to the number of lines in selectList
      attach line n of selectList,line n-1 of selectList
      attach line n-1 of selectList,line n of selectList
      drag from the loc of button ID (line n of selectList) to the loc of button ID (line n-1 of selectList)
    end repeat
    choose browse tool
  end if
end mouseUp

on attach a,b
  if word 1 of the script of button ID b is not in line 2 of the script of button ID a then
    get the script of button ID a
    put word 1 of the script of button ID b & "," before line 2 of it
    set the script of button ID a to it
  end if
end attach




-- part 44 (button)
-- low flags: 00
-- high flags: 0000
-- rect: left=15 top=52 right=64 bottom=71
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name:
----- HyperTalk script -----
on mouseUp
  go to card id 100625
end mouseUp

on mouseDown
  exit mouseDown
end mouseDown

on mouseStillDown
  exit mouseStillDown
end mouseStillDown



-- part 48 (button)
-- low flags: 00
-- high flags: 0000
-- rect: left=15 top=103 right=115 bottom=57
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name:
----- HyperTalk script -----
on mouseUp
  go to card id 101006
end mouseUp

on mouseDown
  exit mouseDown
end mouseDown

on mouseStillDown
  exit mouseStillDown
end mouseStillDown



-- part 49 (button)
-- low flags: 00
-- high flags: 0000
-- rect: left=15 top=155 right=167 bottom=58
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name:
----- HyperTalk script -----
on mouseUp
  go to card id 101184
end mouseUp

on mouseDown
  exit mouseDown
end mouseDown

on mouseStillDown
  exit mouseStillDown
end mouseStillDown



-- part 50 (button)
-- low flags: 00
-- high flags: 0000
-- rect: left=15 top=207 right=219 bottom=101
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name:
----- HyperTalk script -----
on mouseUp
  go to card id 101803
end mouseUp

on mouseDown
  exit mouseDown
end mouseDown

on mouseStillDown
  exit mouseStillDown
end mouseStillDown



-- part 51 (button)
-- low flags: 00
-- high flags: 0000
-- rect: left=15 top=259 right=271 bottom=66
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name:
----- HyperTalk script -----
on mouseUp
  go to card id 105423
end mouseUp

on mouseDown
  exit mouseDown
end mouseDown

on mouseStillDown
  exit mouseStillDown
end mouseStillDown



-- part 52 (button)
-- low flags: 00
-- high flags: 2000
-- rect: left=451 top=9 right=42 bottom=485
-- title width / last selected line: 0
-- icon id / first selected line: 19104 / 19104
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Prev
----- HyperTalk script -----
on mouseUp
  if the commandKey is up then
    -- do regular dissolve or wipe
    if (field "Title" of prev card of this background) is field "Title" of this card then
      visual effect dissolve
    else
      visual effect wipe right
    end if
    go to prev card of this background
  else
    -- Copy this card to the next one
    doMenu "Copy Card"
    doMenu "Paste Card"
    newCard
  end if
end mouseUp



-- part 53 (button)
-- low flags: 80
-- high flags: A002
-- rect: left=73 top=320 right=338 bottom=122
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: New
----- HyperTalk script -----
on mouseDown
end mouseDown

on mouseStillDown
end mouseStillDown

on mouseUp
  doMenu "New Card"
end mouseUp